Add app-misc/solaar-9999 from haarp overlay

app-misc/solaar/Manifest

@@ -0,0 +1 @@
+EBUILD solaar-9999.ebuild 1325 SHA256 7a3571429ec98eb9d2545a334ad4da325386163f20b2c38ef3d33248d88d4278 SHA512 e6bd1c57581e0b2219696c437af847f0737c1e4185fca739cbf760bac30b1477467c4c00d01016144248d16fbdbb29012c5b5886ac5b8aa072ac0f9b05cec7eb WHIRLPOOL 0a560ee852be9419130cde925d19a4ac3d365f001539fe02a88d2e074699bfa60c7f601c6133b92d8a5032bccb43b5e2f0da3ace82284d0908f76df8e1692b85

app-misc/solaar/solaar-9999.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1 udev user linux-info gnome2-utils git-r3
+
+DESCRIPTION="A Linux device manager for Logitech's Unifying Receiver peripherals"
+HOMEPAGE="https://pwr.github.com/Solaar/"
+EGIT_REPO_URI="https://github.com/pwr/Solaar.git"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc"
+
+RDEPEND=">=dev-python/pyudev-0.13[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]
+	dev-libs/libappindicator"
+
+CONFIG_CHECK="~HID_LOGITECH_DJ ~HIDRAW"
+
+python_prepare_all() {
+	# don't autostart (bug #494608)
+	sed -i '/yield autostart_path/d' setup.py || die
+
+	# grant plugdev group rw access
+	sed -i 's/#MODE=/MODE=/' rules.d/42-logitech-unify-permissions.rules || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	udev_dorules rules.d/*.rules
+
+	dodoc docs/devices.md
+	if use doc; then
+		dodoc -r docs/*
+	fi
+}
+
+pkg_postinst() {
+	enewgroup plugdev
+
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		elog "Users must be in the plugdev group to use this application."
+	fi
+
+	gnome2_icon_cache_update
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postrm() { gnome2_icon_cache_update; }