gentoo-overlays
/
smoverlay
1
0
Fork 0
Code Issues Pull Requests Releases Wiki Activity

Add some stuff from kde overlay

This commit is contained in:
Sergey Morozov 2016-11-02 09:59:03 +03:00
parent d2040c4e18
commit cc1b2926fb
10 changed files with 309 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
app-cdr/k3b/Manifest Normal file
View File

@ -0,0 +1 @@
EBUILD k3b-9999.ebuild 3326 SHA256 d627ec0466db31952bcb7efbee29aa54a5bbfb0e228f88f68871e70a14a1d9b9 SHA512 80f9c5f8261c214e73ec8fb35a666468db7eebfaccefec20d48abdb447641974756072dcd136aa7ffe46290ff583961497fc71a3559ecf1e93c77fe09f8ba88c WHIRLPOOL 9438133b6ad55b5af7bccd78afe42edfbf80a74cd8fe25d6e417d6130e3cca2bde3ded28d256c88c4cd30133e58b3f88660240b06cf7966921f9713abc0939c4

120
app-cdr/k3b/k3b-9999.ebuild Normal file
View File

@ -0,0 +1,120 @@
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
KDE_HANDBOOK="forceoptional"
KDE_TEST="optional"
inherit kde5
DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
HOMEPAGE="http://www.k3b.org/"
[[ ${KDE_BUILD_TYPE} = release ]] && SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
LICENSE="GPL-2 FDL-1.2"
[[ ${KDE_BUILD_TYPE} = release ]] && KEYWORDS="~amd64 ~x86"
IUSE="dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis"
DOCS=( {FAQ,PERMISSIONS,README}.txt )
DEPEND="
$(add_frameworks_dep karchive)
$(add_frameworks_dep kbookmarks)
$(add_frameworks_dep kcmutils)
$(add_frameworks_dep kcompletion)
$(add_frameworks_dep kconfig)
$(add_frameworks_dep kconfigwidgets)
$(add_frameworks_dep kcoreaddons)
$(add_frameworks_dep kfilemetadata)
$(add_frameworks_dep ki18n)
$(add_frameworks_dep kiconthemes)
$(add_frameworks_dep kio)
$(add_frameworks_dep kjobwidgets)
$(add_frameworks_dep knewstuff)
$(add_frameworks_dep knotifications)
$(add_frameworks_dep knotifyconfig)
$(add_frameworks_dep kservice)
$(add_frameworks_dep kwidgetsaddons)
$(add_frameworks_dep kxmlgui)
$(add_frameworks_dep solid)
$(add_kdeapps_dep libkcddb)
$(add_qt_dep qtdbus)
$(add_qt_dep qtgui)
$(add_qt_dep qtnetwork)
$(add_qt_dep qtwebkit)
$(add_qt_dep qtwidgets)
$(add_qt_dep qtxml)
media-libs/libsamplerate
dvd? ( media-libs/libdvdread )
ffmpeg? (
libav? ( media-video/libav:= )
!libav? ( media-video/ffmpeg:0= )
)
flac? ( >=media-libs/flac-1.2[cxx] )
mp3? ( media-sound/lame )
mad? ( media-libs/libmad )
musepack? ( >=media-sound/musepack-tools-444 )
sndfile? ( media-libs/libsndfile )
taglib? ( >=media-libs/taglib-1.5 )
vorbis? ( media-libs/libvorbis )
"
RDEPEND="${DEPEND}
app-cdr/cdrdao
media-sound/cdparanoia
virtual/cdrtools
dvd? (
>=app-cdr/dvd+rw-tools-7
encode? ( media-video/transcode[dvd] )
)
emovix? ( media-video/emovix )
sox? ( media-sound/sox )
vcd? ( media-video/vcdimager )
!app-cdr/k3b:4
"
DOCS+=( ChangeLog )
REQUIRED_USE="
mp3? ( encode )
sox? ( encode )
"
src_configure() {
local mycmakeargs=(
-DK3B_BUILD_API_DOCS=OFF
-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
-DK3B_ENABLE_HAL_SUPPORT=OFF
-DK3B_ENABLE_MUSICBRAINZ=OFF
-DK3B_DEBUG=$(usex debug)
-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
-DK3B_ENABLE_TAGLIB=$(usex taglib)
-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
)
kde5_src_configure
}
pkg_postinst() {
kde5_pkg_postinst
echo
elog "If you get warnings on start-up, uncheck the \"Check system"
elog "configuration\" option in the \"Misc\" settings window."
echo
local group=cdrom
use kernel_linux || group=operator
elog "Make sure you have proper read/write permissions on optical device(s)."
elog "Usually, it is sufficient to be in the ${group} group."
echo
}

1
kde-apps/libkcddb/Manifest Normal file
View File

@ -0,0 +1 @@
EBUILD libkcddb-9999.ebuild 1063 SHA256 2a229a2dc525114abfc850d011888df0f7c540a2ef615dd3185883462443225e SHA512 0dc999e8784d5b40516bec88eaa28a7cd8e4ce4a694f94db1926d1958fb0e4aa1d9395c8b9bf52031744979bc263d9c5a7757bbc5ce37323e69145e184f6c723 WHIRLPOOL 78e7742959dac45335a65ed4d189c52c36f5791e31f8c13c59aadafd92cf24b2a74daa129df25993c3a2122e873ee2fe1ebb0e829a7dc73c24ea3766c265a236

52
kde-apps/libkcddb/libkcddb-9999.ebuild Normal file
View File

@ -0,0 +1,52 @@
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
KDE_BLOCK_SLOT4="false"
KDE_HANDBOOK="forceoptional"
KDE_TEST="true"
inherit kde5
DESCRIPTION="KDE library for CDDB"
LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
KEYWORDS=""
IUSE="musicbrainz"
# tests require network access and compare static data with online data
# bug 280996
RESTRICT=test
DEPEND="
$(add_frameworks_dep kcodecs)
$(add_frameworks_dep kconfig)
$(add_frameworks_dep kconfigwidgets)
$(add_frameworks_dep kcoreaddons)
$(add_frameworks_dep ki18n)
$(add_frameworks_dep kio)
$(add_frameworks_dep kwidgetsaddons)
$(add_qt_dep qtgui)
$(add_qt_dep qtnetwork)
$(add_qt_dep qtwidgets)
musicbrainz? ( media-libs/musicbrainz:5 )
"
RDEPEND="${DEPEND}"
src_prepare() {
kde5_src_prepare
if ! use handbook ; then
pushd kcmcddb > /dev/null
cmake_comment_add_subdirectory doc
popd > /dev/null
fi
}
src_configure() {
local mycmakeargs=(
$(cmake-utils_use_find_package musicbrainz MusicBrainz5)
)
kde5_src_configure
}

1
kde-misc/kdiff3/Manifest Normal file
View File

@ -0,0 +1 @@
EBUILD kdiff3-9999.ebuild 997 SHA256 068f7587585a4747ef0d51089cac216176684644509b6b16f501c4a288f78048 SHA512 4bb8be7b320c6c0b8ae138a0e28889ccc63180106f9a775610662029df72da2307e516816ce12c5a330b46570757537fad6439aeb4c926f64a44962d18a5d9ba WHIRLPOOL bec59da1752f8f02e36f6cd54e6a11ddc8482b3047f68b8095a030759286bdd3975fd59401873cf001894021963e7b76ae3f7bc02f757514315f69804c0f08d7

48
kde-misc/kdiff3/kdiff3-9999.ebuild Normal file
View File

@ -0,0 +1,48 @@
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
EGIT_BRANCH="kf5"
inherit kde5
DESCRIPTION="Frontend to diff3 based on Qt/KF5"
HOMEPAGE="http://kdiff3.sourceforge.net/"
EGIT_REPO_URI="https://anongit.kde.org/scratch/thomasfischer/${PN}"
LICENSE="GPL-2"
KEYWORDS=""
IUSE=""
CDEPEND="
$(add_frameworks_dep kconfig)
$(add_frameworks_dep kconfigwidgets)
$(add_frameworks_dep kcoreaddons)
$(add_frameworks_dep ki18n)
$(add_frameworks_dep kiconthemes)
$(add_frameworks_dep kio)
$(add_frameworks_dep kparts)
$(add_frameworks_dep kwidgetsaddons)
$(add_frameworks_dep kxmlgui)
$(add_qt_dep qtcore)
$(add_qt_dep qtgui)
$(add_qt_dep qtprintsupport)
$(add_qt_dep qtwidgets)
"
DEPEND="${CDEPEND}
sys-devel/gettext
"
RDEPEND="${CDEPEND}
sys-apps/diffutils
!kde-misc/kdiff3:4
"
src_unpack(){
if [[ ${KDE_BUILD_TYPE} = live ]]; then
git-r3_src_unpack
mv "${S}"/${PN}/* "${S}" || die
else
kde5_src_unpack
fi
}

1
kde-misc/krename/Manifest Normal file
View File

@ -0,0 +1 @@
EBUILD krename-9999.ebuild 1276 SHA256 7e98cc1020698b9f32b01b6bcde1ba4e1647334783b3626e0220545bbca74dd2 SHA512 2e48c81b5aa85ce08c0eb73348a76a3779bcc68103f00cc62db9208bd358d58313224217da3e5c567bcbe9ffc2ef5b1a63d3d5f91036174c40a53682be3ab92d WHIRLPOOL 85ca6672d462606152827f8cc258cbe34107e573c401486861bc055d42f959640d7f7b9d8bf7ef1185b575a1af931d2a8fb0b92a356a676d18af7b8532e21eff

54
kde-misc/krename/krename-9999.ebuild Normal file
View File

@ -0,0 +1,54 @@
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit kde5
DESCRIPTION="Powerful batch file renamer"
HOMEPAGE="http://www.krename.net/"
LICENSE="GPL-2"
KEYWORDS=""
IUSE="exif pdf taglib truetype"
COMMON_DEPEND="
$(add_frameworks_dep kcompletion)
$(add_frameworks_dep kconfig)
$(add_frameworks_dep kcoreaddons)
$(add_frameworks_dep kcrash)
$(add_frameworks_dep ki18n)
$(add_frameworks_dep kiconthemes)
$(add_frameworks_dep kio)
$(add_frameworks_dep kitemviews)
$(add_frameworks_dep kjobwidgets)
$(add_frameworks_dep kjs)
$(add_frameworks_dep kservice)
$(add_frameworks_dep kwidgetsaddons)
$(add_frameworks_dep kxmlgui)
$(add_qt_dep qtgui)
$(add_qt_dep qtwidgets)
$(add_qt_dep qtxml)
exif? ( >=media-gfx/exiv2-0.13:= )
pdf? ( >=app-text/podofo-0.8 )
taglib? ( >=media-libs/taglib-1.5 )
truetype? ( media-libs/freetype:2 )
"
DEPEND="${COMMON_DEPEND}
sys-devel/gettext
"
RDEPEND="${COMMON_DEPEND}
!kde-misc/krename:4
"
src_configure() {
local mycmakeargs=(
$(cmake-utils_use_find_package exif Exiv2)
$(cmake-utils_use_find_package taglib Taglib)
$(cmake-utils_use_find_package pdf LIBPODOFO)
$(cmake-utils_use_find_package truetype Freetype)
)
kde5_src_configure
}

2
kde-misc/plasma-applet-weather-widget/Manifest Normal file
View File

@ -0,0 +1,2 @@
DIST plasma-applet-weather-widget-1.6.7.tar.gz 98864 SHA256 2f75b96c713ab2be65af6daa860b8df6c8116a7d54055f51a29e4425171237a7 SHA512 24da3014c652a8c8c39de89d61d33a9d745bb172a7ae7c71ca1a20fb834636d277e839f7d3205bd7349d9bc29c84f05bfb3c3f70c943be65f7acfe2315ce078e WHIRLPOOL 720df748c802b2f606944f15b977c85d0c88f975f3d9dd695a1042ccbae33a9db2b881da535bb2e05e043f5a982ba07488fcfe6eb94e3c75735a8b012bf4b006
EBUILD plasma-applet-weather-widget-1.6.7.ebuild 666 SHA256 7ccb4bcdc852b1eabefe4dbce9710cd02f987eb758d55cb10a5e94f78091a979 SHA512 4f31d53821bb34dfd2d25747cd11e8f91a3f53cf78d012e80c6fbe9df3daa8a5e903c74a5e7dda66c096005dd7fb153b3e359e2bf919a429844a814a2ae201d4 WHIRLPOOL 8569c20ffd7604faadf456bf4ca5141e3299db1169bc3b972b16b5ca03198360bd4b47d895bb7b4e5c51b715ab7762e94e859b6a5329b76733b1e38bf6b18ff2

29
kde-misc/plasma-applet-weather-widget/plasma-applet-weather-widget-1.6.7.ebuild Normal file
View File

@ -0,0 +1,29 @@
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit kde5
DESCRIPTION="Plasma 5 applet for weather forecasts"
HOMEPAGE="http://kde-look.org/content/show.php/Weather+Widget?content=169572
https://github.com/kotelnik/plasma-applet-weather-widget"
if [[ ${KDE_BUILD_TYPE} = live ]] ; then
EGIT_REPO_URI="https://github.com/kotelnik/${PN}.git"
else
SRC_URI="https://github.com/kotelnik/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
fi
LICENSE="GPL-2+"
KEYWORDS="~amd64"
IUSE=""
DEPEND="
$(add_frameworks_dep plasma)
$(add_qt_dep qtdeclarative)
"
RDEPEND="${DEPEND}"
DOCS=( README.md )